@echo off
title AR-ElecArrangement Server
cd /d "%~dp0"

:: Matar proceso previo en el puerto 5505 (si quedó colgado de una corrida anterior)
for /f "tokens=5" %%a in ('netstat -ano 2^>nul ^| findstr ":5505 " ^| findstr "LISTENING"') do (
    taskkill /F /PID %%a >nul 2>&1
)
timeout /t 1 /nobreak >nul

echo.
echo  =====================================================
echo   AR-ElecArrangement
echo   Servidor:  http://localhost:5505
echo   LAN:       http://%COMPUTERNAME%:5505
echo  =====================================================
echo.

:: Usar venv si existe, si no buscar python en el PATH
if exist "%~dp0venv\Scripts\python.exe" (
    set "PY=%~dp0venv\Scripts\python.exe"
) else (
    set "PY=python"
)

:: PYTHONPATH para que ``backend.main`` resuelva ``arelec`` del subpaquete
set "PYTHONPATH=%~dp0backend"

:loop
"%PY%" -m backend.main
echo.
echo Servidor detenido. Reiniciando en 3 segundos... (Ctrl+C para salir)
timeout /t 3 /nobreak >nul
goto loop
